Гэри Розенцвейг - Adobe Flash. Создание аркад, головоломок и других игр с помощью ActionScript
Значение карты берется из массива deck (13) . Оно соответствует метке кадра внутри клипа «deck». Это значение сохраняется в свойстве value клипа, после чего клип отправляется в соответствующий кадр. В свойствах клипа row и col хранится позиция клипа в пирамиде (14) .
Затем вы создаете клипы для стопок карт мастью вниз и мастью вверх (15) . Клип для карт мастью вниз отправляется в кадр «back», показывающий изображение рубашки карты. Другая стопка остается в первом кадре, который пуст.
Переменная firstcard установлена как undefined (16) . Эта переменная содержит значение первой карты в паре, выбираемой самим игроком. Массив stack используется для слежения за судьбой карт из стопки мастью вверх. В случае, когда карта из этой стопки используется, должно быть отыскано значение предыдущей выбранной карты.
В заключение должен быть создан экземпляр клипа рамки (17). В начальный момент он помещается за пределами видимости.startGame();
stop();
function startGame() {
// Тасуем колоду.
createDeck();
(10) → // Выстраиваем карты в пирамиду.
level = 0;
for(row=0;row<7;row++) {
for(i=0;i<=row;i++) {
// Создаем новый клип.
mc = _root.attachMovie("Deck","card"+level,level);
(11) → // Задаем его расположение.
mc._x = i*60-row*30 + 275;
mc._y = row*30 + 50;
(12) → // Задаем масштаб.
mc._xscale = 50;
mc._yscale = 50;
(13) → // Устанавливаем знчение карты.
mc.value = deck.pop();
mc.gotoAndStop(mc.value);
(14) → // Запоминаем позицию карты.
mc.row = row;
mc.col = i;
level++;
}
}
(15) → // Размещаем клипы открытой и закрытой колод.
for(i=0;i<2;i++) {
mc = _root.attachMovie("Deck","stack"+i,level);
mc._x = i*60 + 100;
mc._y = 340;
mc._xscale = 50;
mc._yscale = 50;
level++;
}
// Показываем "рубашку" для закрытой колоды.
_root["stack0"].gotoAndStop("back");
(16) → // Задаем значение первой выбранной карты и массив для открытой колоды.
firstCard = undefined;
stack = new Array();
(17) → // Создаем и размещаем рамку.
outline = _root.attachMovie("outline","outline",1000);
outline._xscale = 50;
outline._yscale = 50;
outline._x = -1000;
}Функция createDeck такая же, как в игре «Двадцать одно». Однако теперь вы сортируете только одну колоду. Результат представляется в виде глобальной переменной deck.
// Создаем перетасованную колоду.
function createDeck() {
// Создаем упорядоченную колоду.
suits = ["c","d","s","h"];
temp = new Array();
for(suit=0;suit<4;suit++) {
for(num=1;num<14;num++) {
temp.push(suits[suit]+num);
}
}
// Выбираем случайные карты, пока не создадим перетасованную колоду.
deck = new Array();
while (temp.length > 0) {
r = int(Math.random()*temp.length);
deck.push(temp[r]);
temp.splice(r,1);
}
}Вместо того, чтобы использовать сценарий клипа или кнопку для обнаружения щелчков мыши, я определю функцию для обработки события onMouseDown.
Сначала она совершает цикл по всем картам в пирамиде и определяет, не совершен ли щелчок по одной из них (18) . Цикл начинается с 28 и совершает обратный отсчет. Таким образом, карты наверху рассматриваются сначала, а карты внизу – потом.
Далее мы проверяем, если по карте был совершен щелчок, то программа определяет, закрывают ли данную карту другие карты пирамиды (19) . Для этого вызывается функция cardPresent вместе со значениями ряда и колонки двух карт, которые могли бы закрывать карту, по которой был совершен щелчок.
Если локальная переменная card все еще не определена, значит, ни одна карта не была выбрана. Нужно еще проверить, не выбрал ли игрок карту из стопки карт с открытой мастью. Эту колоду представляет клип «stack1» (20) .
Если карта была выбрана, а глобальная переменная firstcard все еще не определена, значит, не выбрана никакая другая карта. Ссылка на выбранную карту помещается в firstcard (21).
Если другая карта уже выбрана, значения старой и новой карт складываются. Функция cardValue используется для хранения численных значений карт (22) . Если сумма равна 13, обе карты удаляются при помощи функции removeCard.
Если, с другой стороны, значение firstcard равно 13, значит, это король, и он может быть удален сам по себе (23) .
Если по клипу "stackO" был совершен щелчок, это значит, что игрок решил перенести карту из закрытой колоды в открытую. В этом случае берется последнее значение в массиве deck и используется для изменения кадра клипа «stack1» (24) . Массив stack используется для отслеживания карт, которые перемещаются между стопками.
Чтобы выделить выбранную карту, клип "outline" перемещается в то же положение, что и выбранная карта (25) .
И наконец, проверяется первая карта пирамиды (26) . Если она отсутствует, значит, игрок ее удалил и выиграл игру._root.onMouseDown = function() {
var card = undefined;
(18) → // Смотрим, был ли щелчок по одной из карт пирамиды.
for(var i=27;i>=0;i–) {
if (_root["card"+i].hitTest(_xmouse,_ymouse)) {
var card = _root["card"+i];
break;
}
}
(19) → // Если был, закрывают ли эту карту другие карты?
if (card != undefined) {
if (cardPresent(card.row+1,card.col) or cardPresent(card.row+1,card.col+1)) {
card = undefined;
}
}
(20) → // Был ли щелчок по стопке карт, лежащих мастью вверх?
if (card == undefined) {
if (stack1.hitTest(_xmouse,_ymouse)) {
card = stack1;
}
}
// Проверяем, выбрана ли еще одна карта.
if (card != undefined) {
(21) → // Первая выбранная карта.
if (firstCard == undefined) {
firstCard = card;
// Игнорируем второй щелчок по той же карте.
} else if (firstCard == card) {
(22) → // Если выбраны две карты и их сумма равна 13.
} else if (cardValue(firstCard) + cardValue(card) == 13) {
// Удаляем обе карты.
removeCard(card);
removeCard(firstCard);
firstCard = undefined;
// В противном случае считаем, что это первая выбранная карта.
} else {
firstCard = card;
}
}
(23) → // Если выбрана одна карта, и это «король».
if (cardValue(firstCard) == 13) {
removeCard(firstcard);
firstCard = undefined;
}
(24) → // Если щелкнули по колоде закрытых карт, переворачиваем очередную карту.
if (stack0.hitTest(_xmouse,_ymouse)) {
stack1.value = deck.pop();
stack1.gotoAndStop(stack1.value);
stack.push(stack1.value);
// Когда закрытая колода кончается, удаляем ее.
if (deck.length == 0) {
stack0.removeMovieClip();
}
}
(25) → // Помещаем рамку около выделенной карты.
if (firstCard != undefined) {
outline._x = firstCard._x;
outline._y = firstCard._y;
} else {
outline._x = -1000;
}
(26) → // Если удалена первая карта в пирамиде, значит игрок выиграл.
if (_root["card0"] == undefined) {
gotoAndStop("game over");
}
}Осталось рассмотреть несколько полезных функций. Первая, removeCard, удаляет карту из колоды открытых карт или из пирамиды. Чтобы удалить карту из открытой колоды, она должна просто отправить клип «stack1» к кадру, который представляет предыдущую карту. Именно в этом месте оказывается полезным массив stack. Каждая карта, положенная мастью вверх, добавляется к stack. Чтобы достать карту опять, вам нужно удалить последнюю карту из массива stack и затем обратиться к последниму члену этого массива. Если карта оказалась из пирамиды, то клип просто удаляется.
function removeCard(thisCard) {
if (thisCard == stack1) {
// Удаляем карту из открытой колоды.
stack1.gotoAndStop(1);
stack.pop();
stack1.value = stack[stack.length-1];
stack1.gotoAndStop(stack1.value);
} else {
// Удаляем карту из пирамиды.
thisCard.removeMovieClip();
}
}Следующая функция, cardPresent, проверяет в цикле все карты, чтобы определить, существует ли карта в позиции, определенной аргументами вызова данной функции.
function cardPresent(row, col) {
// Проверяем, существует ли в пирамиде данная карта.
for(var i=0;i<28;i++) {
thisCard = _root["card"+i];
if ((thisCard.row == row) and(thisCard.col == col)) {
return (true);
}
}
return(false);
}Функция cardValue берет свойство value клипа карты, отбрасывает первый символ и возвращает численное значение. Например, если значение value карты равно c9, возвращается число 9.
function cardValue(card) {
// Удаляем первый символ из значения value.
n = card.value;
n = parseInt(n.substr(1,2));
return(n);
}Последняя функция проходит в цикле по всем картам пирамиды и удаляет все оставшиеся карты. Также она удаляет «stackO» и «stack1». Это очищает рабочее поле для подготовки к следующему раунду.
function clearGame() {
// Удаляем карты из пирамиды.
for(var i=0;i<28;i++) {
_root["card"+i].removeMovieClip();
}
// Удаляем обе колоды.
stack0.removeMovieClip();
stack1.removeMovieClip();
}К сведению
Кнопка New на экране имеет простой сценарий и сначала вызывает clearGame, а потом startGame. Это перезапускает игру в любой удобный пользователю момент.
on (press) {
clearGame();
startGame();
}
Другие возможности
Игру можно сделать значительно проще, если вы разрешите игроку переворачивать колоду уже открытых карт и смотреть карты столько раз, сколько он захочет. Вы можете сделать это, опознавая, когда массив deck пуст, и помещая каждую карту из массива stack обратно в массив deck.
Кроме этого пасьянса вы можете создать много других. В моей коллекции более 200 вариантов подобных игр. Большинство из них требует вытаскивания карт и перекладывания из стопки в стопку. Это делает код гораздо более сложным, но не невозможным для опытного программиста.
