Алексей Валиков - Технология XSLT
<list active="Bravo">
<item>Alpha</item>
<item>Bravo</item>
<item>Charlie</item>
</list>
во фрагмент HTML-кода, в котором каждый элемент item должен быть преобразован в соответствующий элемент option, а значение, выбранное во входящем документе атрибутом active элемента list, должно быть помечено булевым атрибутом selected.
Листинг 7.23. Шаблон преобразования, использующий элемент xsl:if<xsl:template match="item">
<option>
<!--
| Если текстовое значение элемента равно
| значению атрибута active его родительского элемента
+-->
<xsl:if test=". = ../@active">
<!-- To выводим атрибут selected -->
<xsl:attribute name="selected">selected</xsl:attribute>
</xsl:if>
<xsl:value-of select="."/>
</option>
</xsl:template>
Результат:
<option>Alpha</option>
<option selected>Bravo</option>
<option>Charlie</option>
ПримечаниеВ данном преобразовании использовался метод вывода "html". Подробнее о методах вывода выходящего документа см. раздел "Контроль вывода документа" 8 главы.
К сожалению, элемент xsl:if в XSLT не может реализовать конструкцию if-then-else (англ. если-то-иначе). Условные выражения такого вида реализуются при помощи элементов xsl:choose, xsl:when и xsl:otherwise.
Элементы xsl:choose, xsl:when, xsl:otherwise
Ниже даны синтаксические конструкции этих элементов:
<xsl:choose>
<!--
| Содержимое: один или более элемент xsl:when, опциональный
| элемент xsl:otherwise
+-->
</xsl:choose>
<xsl:when
test="выражение">
<!-- Содержимое: шаблон -->
</xsl:when>
<xsl:otherwise>
<!-- Содержимое: шаблон -->
</xsl:otherwise>
Элемент xsl:choose содержит один или несколько элементов xsl:when и необязательный элемент xsl:otherwise. При обработке xsl:choose процессор поочередно вычисляет выражения, содержащиеся в атрибутах test элементов xsl:when, приводит их к булевому типу и выполняет содержимое первого (и только первого) элемента, тестовое выражение которого будет равно true. В случае если ни одно из тестовых выражений не обратилось в "истину" и в xsl:choose присутствует xsl:otherwise, процессор выполнит содержимое этого элемента.
Элементы xsl:choose, xsl:when и xsl:otherwise можно совместно использовать для получения конструкции типа if-then-else. Условие вида "если выражение A истинно, то выполнить действие B иначе выполнить действие C", которое в других языках программирования может быть записано, к примеру, как
если
верно условиеА
то
выполнить шаблонB
иначе
выполнить шаблонC
в XSLT может быть определено следующим образом:
<xsl:choose>
<xsl:when test="условиеА">
шаблонB
</xsl:when>
<xsl:otherwise>
шаблонC
</xsl:otherwise>
</xsl:choose>
Вместе с тем, условие вида "если — то — иначе" это не все, на что способен элемент xsl:choose. Возможность указывать несколько элементов xsl:when позволяет записывать более сложные условия выбора вида:
если
верно условие1
то
выполнить шаблон1
иначе если
верно условие2
то
выполнить шаблон2
...
иначе если
верно условиеN
то
выполнить шаблонN
иначе
выполнить шаблонМ
Такой множественный условный переход совершенно прозрачно оформляется в виде следующей xsl:choose-конструкции:
<xsl:choose>
<xsl:when test="условие1">
шаблон1
</xsl:when>
<xsl:when test="условие2">
шаблон2
</xsl:when>
<!-- ... -->
<xsl:when test="условиеN">
шаблонN
</xsl:when>
<xsl:otherwise>
шаблонМ
</xsl:otherwise>
</xsl:choose>
Циклическая обработка
Элемент xsl:for-each
Конструкция этого элемента такова:
<xsl:for-each
select="выражение">
<!-- Содержимое: несколько элементов xsl:sort, шаблон -->
</xsl:for-each>
Элемент xsl:for-each используется для создания в выходящем документе повторяемых частей структуры. Обязательный атрибут select указывает выражение, результатом вычисления которого должно быть множество узлов. Шаблон, содержащийся в xsl:for-each, будет выполнен процессором для каждого узла этого множества.
ПримерМы можем использовать xsl:for-each для того, чтобы создать список гипертекстовых ссылок для документа вида.
Листинг 7.24. Входящий документ<html>
<head>
<title>I'm just a simple page...</title>
</head>
<body>
Please visit <a href="http://www.aaa.com">this link</a>.
Or <a href="http://www.bbb.com">this one</a>.
Or visit <a href="http://www.ccc.com">this site</a>.
Or click <a href="http://www.ddd.com">here</a>.
</body>
</html>
Будем считать, что в этом документе элементы гипертекстовых ссылок а являются потомками элемента body, который находится в элементе html.
Листинг 7.25. Шаблон преобразования<xsl:template match="/">
<links>
<xsl:for-each select="/html/body//a">
<a href="{@href}">
<xsl:value-of select = "@href"/>
</a>
</xsl:for-each>
</links>
</xsl:template>
Листинг 7.26. Результат преобразования<links>
<a href="http://www.aaa.com">http://www.aaa.com</a>
<a href="http://www.bbb.com">http://www.bbb.com</a>
<a href="http://www.ccc.com">http://www.ccc.com</a>
<a href="http://www.ddd.com">http://www.ddd.com</a>
</links>
Элемент xsl:for-each изменяет контекст преобразования. Множество узлов, возвращаемое выражением в атрибуте select, становится текущим множеством узлов, а узел, шаблон для которого выполняется в данный момент, становится текущим узлом.
Как мы знаем, множества узлов в XSLT не имеют внутреннего порядка. Однако, обработка узлов в xsl:for-each будет происходить в так называемом порядке просмотра документа, который зависит от того, какое выражение использовалось для вычисления обрабатываемого множества. Порядок обработки множества узлов в xsl:for-each может быть также изменен элементами xsl:sort, которые могут присутствовать в xsl:for-each. Элемент xsl:sort задает сортировку обрабатываемого множества узлов, изменяя, таким образом, порядок просмотра, что часто бывает очень полезно.
Глава 8
Дополнительные элементы и функции языка XSLT
Дополнительные элементы и функции
В этой главе разбираются дополнительные элементы и функции языка XSLT, которые выполняют в преобразованиях различные задачи, непосредственно не связанные с созданием узлов выходящего документа. Дополнительные элементы и функции XSLT расширяют возможности преобразования, предоставляя разного рода вспомогательный сервис.
К дополнительным элементам XSLT мы отнесем следующие:
□ xsl:preserve-space и xsl:strip-space — работа с пробельными символами;
□ xsl:message — сообщения процессора;
□ xsl:sort — сортировка множеств перед обработкой;
□ xsl:namespace-alias — определение псевдонимов пространств имен;
□ xsl:key — определение ключей;
□ xsl:number — нумерация;
□ xsl:decimal-format — определение десятичного формата;
□ xsl:output — контроль сериализации.
В XSLT также определяются дополнительные функции, расширяющие базовую библиотеку функций XPath:
□ key — использование ключей;
□ format-number — форматирование чисел;
